エクセルリストを瞬時にXMLへ変換するマクロ：活用ガイド

エクセルデータを瞬時にXML形式でクリップボードにコピーするマクロをご紹介します。

このマクロが実現すること
コード挿入
マクロの実行時の操作
マクロ実行後の確認事項
使用時の注意点

このマクロが実現すること

このマクロは、エクセルの指定した範囲のデータを簡単にXML形式に変換し、クリップボードにコピーすることが可能にします。これにより、データの共有や他のプログラムでの利用が非常に簡単になります。

それをWeb上へアップロードすることで別の場所から再利用することができます。

コード挿入

下記のコードをVBAエディタから標準モジュールにコピー＆ペーストしてマクロをセットアップしてください。「ConvertRangeToXMLAndCopyToClipboard」というマクロが作成されます。

Sub ConvertRangeToXMLAndCopyToClipboard()
    On Error Resume Next

    ' Input 1: Get Dataset name
    Dim datasetName As String
    datasetName = InputBox("データセットの名前を入力してください:")
    If datasetName = "" Then Exit Sub

    ' Input 2: Get Row Meaning
    Dim rowMeaning As String
    rowMeaning = InputBox("行の意味を入力してください:")
    If rowMeaning = "" Then Exit Sub

    ' Input 3: Get Range
    Dim rng As Range
    Set rng = Application.InputBox("リストの範囲を選択してください:", Type:=8)
    If rng Is Nothing Then Exit Sub

    ' Check for merged cells
    Dim cell As Range
    For Each cell In rng
        If cell.MergeCells Then
            MsgBox "セルの結合を解除してください", vbExclamation
            Exit Sub
        End If
    Next cell

    ' Generate XML
    Dim xml As String
    xml = "<" & datasetName & ">" & vbCrLf
    
    Dim i As Long, j As Long
    For i = 2 To rng.Rows.Count
        xml = xml & "  <" & rowMeaning & ">" & vbCrLf
        For j = 1 To rng.Columns.Count
            xml = xml & "    <" & rng.Cells(1, j).Value & ">" & rng.Cells(i, j).Value & "</" & rng.Cells(1, j).Value & ">" & vbCrLf
        Next j
        xml = xml & "  </" & rowMeaning & ">" & vbCrLf
    Next i
    
    xml = xml & "</" & datasetName & ">"
    
    ' Copy to Clipboard
    Dim MSForms_DataObject As Object
    Set MSForms_DataObject = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
    MSForms_DataObject.SetText xml
    MSForms_DataObject.PutInClipboard

    MsgBox "XMLがクリップボードにコピーされました", vbInformation
End Sub